Kalender

[Sven]

Dat werkt. Ik dacht er aan om dat eerder aan te geven of de pin wel klopte, want ik had gelezen over het verschil tussen digitaal en PWM, maar omdat de dimmende LED werkte met het testbestand op pin 9 dacht ik dat het wel moest werken.

Nu moet ik alleen de richting omkeren.

[bask185]

richting van de servo of de led?

[Sven]

Servo. Ik heb het voor elkaar gekregen door de verschillende dingen om te draaien en aan te passen. Het werkt, dus ik neem aan dat ik dat goed gedaan heb (zie onder).

Iedereen bedankt voor de snelle hulp! Als ik het ingebouwd heb, zal ik het laten zien.

Code Selecteer Uitklappen

#include <Servo.h>

Servo servo ;

int     pos        = 0 ;
int     dutyCycle  = 0 ;

const int servoPin = 8 ;
const int ledPin   = 11 ;

const int fadeDelay        = 10 ;
const int servoDelay       = 15 ; // Snelheid van servo in beide richtingen
const int servoLowerDegree = 100 ;
const int servoUpperDegree = 140 ;

int servoLowerUs ;
int servoUpperUs ;

enum states
{
  fadeIn,
  moveServoIn,
  fadeOut,
  moveServoOut
} ;

uint8_t state = fadeIn ;

void setup()
{
  servo.attach(servoPin);  // attaches the servo on pin 8 to the servo object
  pinMode( ledPin, OUTPUT ) ;

  servoLowerUs = map( servoLowerDegree, 0, 180, 1000, 2000 ) ; // Dit schaalt de gewenste graden om naar de corresponderende tijd in uS
  servoUpperUs = map( servoUpperDegree, 0, 180, 1000, 2000 ) ;

}

void loop()
{
  int i ;

  switch( state )
  {
 
  case fadeOut:
    for( i = 255 ; i > 0 ; i -- )
    {
      analogWrite(ledPin, i);
      delay(fadeDelay) ;
    }
    state = moveServoIn ;
    break ;

  case moveServoIn:
    for( i = servoLowerUs ; i < servoUpperUs ; i ++ )
    {
      servo.writeMicroseconds(i) ;
      delay(servoDelay) ;
      // delayMicroseconds(servoDelay) ;
    }
    state = fadeIn ;
    break ;

  case fadeIn:
    for( i = 0 ; i < 255 ; i ++ )  // 1 stapje per keer is beter, kleinere stapgrootte
    {
      analogWrite(ledPin, i);
      delay(fadeDelay) ;
      // delayMicroseconds() ; // dit kan ook, dit is een delay in uS zoals de naam al zegt..
    }
    state = moveServoOut ;
    break ;
   
  case moveServoOut:
    for( i = servoUpperUs ; i > servoLowerUs ; i -- )
    {
      servo.writeMicroseconds(i) ;
      delay(servoDelay) ;
      // delayMicroseconds(servoDelay) ;
    }
    state = fadeOut ;
    break ;
  }
}

[rjr]

#4
Servo.write pakt alleen gehele getallen en geen floats. Behalve servo.write bestaat er ook servo.writeMicroseconds(). Deze geeft je een veel grotere resolutie, maar je moet niet het aantal graden invullen maar het aantal us dat de puls moet duren.

Bas

Ter info voor mezelf, gewoon even wat ik me dan afvraag:
Geeft dit niet een verloop van de stappen van de servo?
Als je aangeeft hoe lang iets moet lopen kun je toch kleine afwijkingen krijgen als de CPU ook andere zaken aan het doen is? Weet niet hoe nauwkeurig Arduino hier mee is.
Zal niet direct zichbaar zijn, maar misschien wel bij heel lang lopen, en wat hij verder allemaal moet uitvoeren.

Verder wel zeker interessant om te gebruiken, vond zelf de stappen met de servo ook al wat grof.

Groet,
Roelco

[meino]

Ik weet niet of dat veel zin heeft. Mijn ervaring met servo's is dat ze vrij onnauwkeurig zijn kwa preciese positionering. Ik ben al blij als ze binnen een marge van (geschatte) 5graden ergens terechtkomen. Bij wissels niet zo'n probleem omdat ik er altijd een verend deel in de aandrijving heb, maar bij een seinarm blijft het me irriteren dat ik nooit een preciese stand kan bereiken. Wil je precies positioneren dan zul je met een stappenmotor moeten werken.

Groet Meino

[bask185]

Een "servo" systeem is een motor systeem met terugkoppeling. Die kleine hobby servo's die wij gebruiken hebben ook terugkoppeling. Ze zullen altijd draaien naar de stand die jij met de arduino verstuurt. En daar blijven ze dan ook staan.

De pulsen worden gegenereerd op interrupts basis. Dat gebeurt op de achtergrond met redelijke exacte intervallen.

Die hobby servo's hebben verder geen snelheidsregeling, daarom laat je ze meestal 1 graad per tijdstapje opschuiven. Of in geval met writeMicrosconds doe je met kleinere stapjes voor een vloeiendere beweging.

vond zelf de stappen met de servo ook al wat grof.

Eens. Maar het verschilt wel per toepassing. Voor een wissel is het prima, voor een overwegboom wat minder.  Ik heb in dit draadje 3j terug een paar filmpjes gemaakt. Ik kan me niet herinneren of ik toen al writeMicroseconds had gebruikt.

Ik heb ze zelf wel voor seinarmen gebruikt en ik was daar wel tevreden over.
https://youtu.be/gLNPEMmPiQg

Mvg,

Bas

[Sven]

Ik heb een video van de actie gemaakt. Ik probeer alleen nog een stoppunt in te bouwen. Een wachtmoment voordat de actie herhaald wordt (een wachttijd of de druk van een knop). Dit moet worden geplaatst voor de LED die aan gaat. Ik heb geprobeerd een "delay(500) ;" in te bouwen, maar dat is merkwaardig genoeg lastiger dan ik zou denken. Het enige dat ik voor elkaar krijg is dat de LED de gehele tijd blijft branden. Waar moet dit moment?

Link: https://youtu.be/4YFzO81VgUw

https://youtube.com/v/4YFzO81VgUw

[meino]

Ik heb ze zelf wel voor seinarmen gebruikt en ik was daar wel tevreden over.
https://youtu.be/gLNPEMmPiQg

Ik heb ze zelf ook voor seinen gebruikt.
https://www.youtube.com/v/8-BYXuSmZZA

Het bewegen van de armen gaat perfect. Alleen de eindstanden zijn nooit stabiel. Als ik die posities bepaald heb en dan zijn ze een paar dagen later alweer verlopen. Dat kan te maken hebben met temperatuur en zo, maar de eindstanden verlopen altijd bij mij. Dus  dat moet ik nog eens gaan aanpakken.

Groet Meino

[bask185]

Het is ellendig dat die potmeter niet naar buiten is geleid. Het zou zo handig als je besturing kan zien wat de stand is.

Eric van C was bezig met die microsteppers voor armseinen. Dat is wellicht een uitkomst.

Ik heb in december nog een idee geplaatst over een DCC print waarin een servo en limit switches passen. Die stand kan je aanpassen door de servo in de print te verschuiven. Het is mijn hoop dat die limit switches tot constante eindposities lijden. Misschien dat 1 of 2 limit switches er bij iets voor je kunnen betekenen?


Bas

[meino]

Bas

ik heb ook aan die microsteppers gedacht. Met stappenmotors heb ik ook ervaring (draaischijf). Die kun je heel precies laten bewegen. Nadeel is dat ze geen vast nulpunt hebben, voor een draaischijf geen probleem, die kun je makkelijk met een Hallsensor en een magneetje op de brug kalibreren, maar voor seinen wordt dat lastiger. Ik denk zelf nu aan een constructie met verenstaal en een fysieke begrenzing van de beweging. Een beetje analoog met de constructie van de wisselaandrijvingen die ik momenteel maak voor Kranenberg.

Groet Meino

[bask185]

Nadeel is dat ze geen vast nulpunt hebben

Je moet kijken naar die lineaire stappen dingen, niet die roterende. Die hebben al 2 fysieke eindpunten. Je kan hem bij opstarten zonder schade tegen een van zijn 0 punten aandraaien. Dan weet je zeker dat die 'thuis' staat en vanaf dat moment kan je verder.

Bas

[bask185]

Wat die pause betreft.

Ik heb de code aangepast en voorzien van een nieuwe state genaamd 'pause'. De 'pauseTime' is een constante en die staat voor nu op 500ms voor Sven om aan te passen.

Tevens heb ik een extra input aangemaakt waarmee je de pause kan skippen. Die heet 'continuButton'. Die dien je aan GND te verbinden met een schakelaar. (als je die schakelaar wilt, that is)

Code Selecteer Uitklappen


#include <Servo.h>

Servo servo ;

int     pos        = 0 ;
int     dutyCycle  = 0 ;

long      prevTime ;

const int continuButton = 7 ;
const int servoPin = 8 ;
const int ledPin   = 11 ;

const int fadeDelay        = 10 ;
const int servoDelay       = 15 ; // Snelheid van servo in beide richtingen
const int servoLowerDegree = 100 ;
const int servoUpperDegree = 140 ;

int servoLowerUs ;
int servoUpperUs ;

const int pauseTime = 500 ;

enum states
{
  pause,
  fadeIn,
  moveServoIn,
  fadeOut,
  moveServoOut
} ;

uint8_t state = pause ;

void setup()
{
  servo.attach(servoPin);  // attaches the servo on pin 8 to the servo object
  pinMode( ledPin, OUTPUT ) ;
  pinMode( continuButton, INPUT_PULLUP ) ;

  servoLowerUs = map( servoLowerDegree, 0, 180, 1000, 2000 ) ; // Dit schaalt de gewenste graden om naar de corresponderende tijd in uS
  servoUpperUs = map( servoUpperDegree, 0, 180, 1000, 2000 ) ;

}

void loop()
{
  int i ;

  switch( state )
  {
  case pause:
    if( millis() - prevTime >= pauseTime        // if the time expires
    ||  digitalRead( continuButton ) == LOW )   // OR the button is pressed. Continu
    {
      state = fadeOut ;
    }
    break ;

  case fadeOut:
    for( i = 255 ; i > 0 ; i -- )
    {
      analogWrite(ledPin, i);
      delay(fadeDelay) ;
    }
    state = moveServoIn ;
    break ;

  case moveServoIn:
    for( i = servoLowerUs ; i < servoUpperUs ; i ++ )
    {
      servo.writeMicroseconds(i) ;
      delay(servoDelay) ;
      // delayMicroseconds(servoDelay) ;
    }
    state = fadeIn ;
    break ;

  case fadeIn:
    for( i = 0 ; i < 255 ; i ++ )  // 1 stapje per keer is beter, kleinere stapgrootte
    {
      analogWrite(ledPin, i);
      delay(fadeDelay) ;
      // delayMicroseconds() ; // dit kan ook, dit is een delay in uS zoals de naam al zegt..
    }
    state = moveServoOut ;
    break ;
 
  case moveServoOut:
    for( i = servoUpperUs ; i > servoLowerUs ; i -- )
    {
      servo.writeMicroseconds(i) ;
      delay(servoDelay) ;
      // delayMicroseconds(servoDelay) ;
    }
    state = pause ;
    prevTime = millis() ; // store current time for pause delay
    break ;
  }
}
[code]
Bovenstaande code compileert maar is ongetest.

Mvg,

Bas

[Sven]

Brilliant, hartstikke bedankt. Als je straks ziet waar het voor is (en het werkt) ga je blij worden.